Renaming User Accounts in Active Directory with VBScript

This one proved to be a little more difficult then I first thought. We were able to get a few attributes to change, but in further testing; I found that AD was throwing a fit. The problem was resolved using the ADSI Editor Snap-in. What I did was watch each value and whether or not the correct value was reflected in the User accounts properties. The following code relies on a text file containing the old and new user names formatted as such:

OldUserName1,NewUserName1
OldUserName2,NewUserName2
OldUserName3,NewUserName3

You can modify the code to import the usernames anyway that works for you. Also, do not forget to change the variables ParentDN and strUPNSuffix to match your environments.

' ================================
' RenameUSerAccounts.vbs
' Author: Jason A. Yoder, MCT
' Date: May 15, 2009
'
' Required Files:
' - A Text file named "names.txt". In this script, the file
' location is hard coded.
' The format for the text file is %OldUserName%,%NewUserName%
'
' Other Information:
' - The interesting part of this code is in the Do While...Loop.
' It does not matter how you get the data into the script
' as long as you have the ParentDN and both old and new usernames.
' ================================

Const ForReading = 1
ParentDN = "OU=HR,DC=FourthCoffe,DC=com" ' Change this line to reflect your environment.
strUPNSuffix = "ens.com" ' Change this line to reflect your environment.

' Read in the data file of old and new user names.
Set objFilesys = CreateObject("Scripting.FileSystemObject")
Set objFileText = objFileSys.OpenTextFile("C:\Users\Administrator\Desktop\Test\Names.txt", ForReading, true)

Do Until objFileText.AtEndOfStream '
strText = objFileText.Readline ' Reads the Names.txt file one line at a time.
aryText = Split(strText,",") ' Slipts each value into different cells of aryText.

strUserOldName = aryText(0)
strUserNewName = aryText(1)

set objCont = GetObject("LDAP://" & ParentDN)
objCont.MoveHere "LDAP://cn=" & strUserOldName & "," & ParentDN, "cn=" & strUserNewName
set objUser = GetObject("LDAP://cn=" & strUserNewName & "," & ParentDN)

objUser.Put "sAMAccountName",strUserNewName
objUser.Put "userPrincipalName",strUserNewName & "@" & strUPNSuffix
objUser.Put "GivenName",strUserNewName
objUser.Put "DisplayName",strUserNewName

objUser.SetInfo
Loop

WScript.Echo "Done"

Comments

With the AD Recycle Bin Turned on, What Happens when you Create a User Account with a Password that does not meet the Password Policy?

This was an interesting observation from one of my Windows Server 2012 classes. While working with the AD Recycle bin in a lab, one of my students discovered some interesting accounts that were created. When he created user accounts that did not meet password complexity requirements, an account is temporarily made and then deleted. When a new password is provided that meets the password requirements, then a new account is made. We discovered this in two places. First off in the Active Directory Administrative Center. This is what caused the initial confusion. Take a look. This is in the Deleted Objects OU. You can see multiple deleted accounts for Test2 and one for Test3. Test3 is a valid, functioning user account. Using the PowerShell command Get-ADObject –IncludeDeletedObjects –Filter * –Properties ObjectSID we can see that indeed, two accounts were created, with one of them deleted. Notice the RID portion of the SID is different. ...

Sticky Key problem between Windows Server 2012 and LogMeIn

This week I instructed my first class using Windows Server 2012 accessed via LogMeIn and discovered a Sticky Key problem every time you press the Shift key. Here is my solution to resolve this. First off, in the Preferences of LogMeIn for the connection to the Windows Server, click General . Change the Keyboard and mouse priority to Host side user and click Apply at the bottom. On the Windows 2012 server, open the Control Panel – Ease of Access – Change how your keyboard works . Uncheck Turn on Sticky Keys . Click Set up Sticky Keys . Uncheck Turn on Sticky Keys when SHIFT is pressed five times . Click OK twice. If you are using Windows Server 2012 as a Hyper-V host, you will need to redo the Easy of Use settings on each guest operating system in order to avoid the Sticky Key Problem. Updated Information: March 20, 2013 If you continue to have problems, Uncheck Turn on Filter Keys .

Backup and Restore AD LDS with DSDBUTIL.exe

Active Directory Lightweight Directory Services allow you to create a directory service that allows applications to have access to user accounts, groups, and authentication similar to Active Directory Domain Services. The big advantage here is that the schema of the directory service will not be bound by the rules of an Active Directory database. Exchange 2007/2010, for example, use an instance of AD LDS on the Edge Transport Server to provide for user authentication from the internet. Because your Active Directory database is not exposed to the internet, this is more secure. Applications will handle most of the dirty work should they require AD LDS. You may want to make sure the database is being backed up and also have a restore plan in place. Should the database become corrupt, the application that uses that database will fail. This document will walk you through backing up and restoring an instance of AD LDS using the dsdbutil.exe command. Fi...

Jason Yoder, MCT

Search This Blog